/**** ***** ***** ***** ***** ***** ***** ***** ***** *****
*
* 日本疫学会プレセミナー
* Rで実践！ 美しい Figure ＆ Table を作成しよう
* Stataでの実行に関するフォロー
* by Toshiharu Mitsuhashi @sankyoh
* Part 1. 導入
*
***** ***** ***** ***** ***** ***** ***** ***** ***** ****/

/***************************************************************************
*
* データ読み込み・整理
*
***************************************************************************/

import excel "NHEFS.xlsx", firstrow clear

label define death 0 "Alive" 1 "Death"
label values death death

gen pack_year_n = (smokeintensity/20) * smokeyrs

compress
save nhefs.dta, replace

/***************************************************************************
*
* 外部コマンドのインストール
* 未インストールの外部コマンドをインストールして下さい。
* ネット環境にもよりますが、少し時間がかかります。
*
***************************************************************************/

ssc install schemepack, replace   // イケてるグラフテーマ
ssc install stripplot, replace    // dotplotの（上位）互換コマンド
ssc install fre, replace          // 度数分布表。tabの互換コマンド
ssc install table1, replace       // 記述統計表を作成
ssc install bihist, replace       // 上下に向いたヒストグラム
ssc install covbal, replace       // 共変量バランスのチェック
// ssc install dag, replace       // DAGを用いた解析（今回はつかいません）

// グラフを1枚にまとめるときに、Legendを1つだけにするコマンドgrc1leg
net install grc1leg.pkg, replace from(http://www.stata.com/users/vwiggins/)

// labmaskのインストール
net install gr0034.pkg, replace from(http://www.stata-journal.com/software/sj8-2/)

// カラーパレット
net install gr0075.pkg, replace from(http://www.stata-journal.com/software/sj18-4/)

/***************************************************************************
*
* Section 3 ggplot2 (Stataではtwowayが相当)
*
***************************************************************************/

// データ読み込み
use nhefs, clear

////////// ////////// ////////// //////////
* Section 3.2 基本コマンド
////////// ////////// ////////// //////////
twoway // 真っ白になる

////////// ////////// ////////// //////////
* Section 3.3 基本コマンド+オプション1
////////// ////////// ////////// //////////
twoway scatter dbp sbp

////////// ////////// ////////// //////////
* Section 3.4 基本コマンド+オプション2
////////// ////////// ////////// //////////

twoway scatter dbp sbp, ///
	scheme(white_tableau) /// グラフテーマ
	msymbol(oh)           /// プロットシンボル（ohは小さい中抜きの○の意味）
	mcolor(orange %30)    //　プロット色と透明度

////////// ////////// ////////// //////////
* Section 3.5 基本コマンド+オプション3
////////// ////////// ////////// //////////

twoway scatter dbp sbp, ///
	scheme(white_tableau) /// グラフテーマ
	msymbol(oh)           /// プロットシンボル（ohは小さい中抜きの○の意味）
	mcolor(orange %30)    ///　プロット色と透明度
	xtitle("SBP(mmHg)")   /// X軸
	ytitle("DBP(mmHg)")   /// Y軸
	xlabel(80(40)240)        /// X軸の範囲
	ylabel(40(20)140)        //  Y軸の範囲

exit